Electromagnetic mass splittings in a SU(3) octet

Note : in Mathematica, greek letters are obtained by using the key "Esc" before and after typing the abreviation of the greek letter with a latine spelling

Theory

octet content and properties

octet of mesons (J^P)=(SuperMinus[0])

Φ={{1/Sqrt[2]π0-1/Sqrt[6]η,πp,Kp},{πm,-1/Sqrt[2]π0-1/Sqrt[6]η,K0},{Km,K0b,Sqrt[2/3]η}}

octet of baryons (J^P)=(SuperPlus[(Underoverscript[-, 2, 1])])

Ψ={{1/Sqrt[2]Σ0-1/Sqrt[6]Λ,Σp,p},{Σm,-1/Sqrt[2]Σ0-1/Sqrt[6]Λ,n},{Ξm,Ξ0,Sqrt[2/3]Λ}}

One should be careful:  Σm and Σp are not charge conjugated

Ψb={{-(Λb/Sqrt[6])+Σ0b/Sqrt[2],Σmb,Ξp},{Σpb,-(Λb/Sqrt[6])-Σ0b/Sqrt[2],Ξ0b},{pb,nb,Sqrt[2/3]*Λb}}

the isospin,  hypercharge and charge operators

Iz=1/2{{1,0,0},{0,-1,0},{0,0,0}}

Y=1/3{{1,0,0},{0,1,0},{0,0,-2}}

Q=1/2 Y +Iz

the isospin, hypercharge and charge of the octet of mesons (J^P)=(SuperMinus[0])

η is isoscalar, ((K^0),(SuperPlus[K])) and ((SuperMinus[K]),(Kb^0) ) are two isodoublet, ((SuperMinus[π]),(π^0),(SuperPlus[π])) is an isovector:

Simplify[Iz.Φ-Φ.Iz]

Simplify[Y.Φ-Φ.Y]

Simplify[Q.Φ-Φ.Q]

the isospin, hypercharge and charge of octet of baryons (J^P)=(SuperPlus[(Underoverscript[-, 2, 1])])

(Λ^0) is an isoscalar, (n,p) and ((SuperMinus[Ξ]) ,(Ξ^0))are two isodoublet, ((SuperMinus[Σ]), (Σ^0), (SuperPlus[Σ])) is an isovector:

Simplify[Iz.Ψ-Ψ.Iz]

Simplify[Y.Ψ-Ψ.Y]

Simplify[Q.Ψ-Ψ.Q]

Mass splittings

the four invariant operators

O1=Ψb.Q.Q.Ψ;

O2=Ψb.Ψ.Q.Q;

O3=Ψb.Q.Ψ.Q;

O4=Ψb.Ψ;

Oα=Expand[Tr[O1]]

Oβ=Expand[Tr[O2]]

Oγ=Expand[Tr[O3]]

Tr [Ψ Ψb] is the identity operator:

Oid=Expand[Tr[O4]]

the relevant mass operator

Note: since Oid is proportional to Id, it does not contribute to mass differences ; we anyway expand the mass operator as an expansion on the 4 invariants

M=α Oα+β Oβ+γ Oγ+δ Oid

Mp=Coefficient[M,p pb]

Mn=Coefficient[M,n nb]

MΛ=Coefficient[M,Λ Λb]

MΣp=Coefficient[M,Σp Σpb]

MΣ0=Coefficient[M,Σ0 Σ0b]

MΣm=Coefficient[M,Σm Σmb]

MΞ0=Coefficient[M,Ξ0 Ξ0b]

MΞm=Coefficient[M,Ξm Ξp]

{MΞm-MΞ0,MΣm-MΣp+Mp-Mn}

Conclusion : MΞm - MΞ0 = MΣm - MΣp + Mp - Mn

Phenomenology

Experimental data for masses (in MeV/(c^2)) of the octet of baryons (J^P)=(SuperPlus[(Underoverscript[-, 2, 1])])

MnE=939.56;
MpE=938.27;
MΞmE=1321.71;
MΞ0E=1314.86;
MΣmE=1197.45;
MΣ0E=1192.64;MΣpE=1189.37;

Comparison with theory

{MΞmE-MΞ0E,MΣmE-MΣpE+MpE-MnE}

(MΞmE-MΞ0E)/(MΣmE-MΣpE+MpE-MnE)